/*This macro takes a folder of stacked three channel images (TxRed, DAPI, FITC) and takes user-defined thresholds to identify particles/cells that are above the given threshold. It applies the same thresholds to all files in the directory. It then saves two Excel files per image stack: one for DAPI and one for FITC. 
Prior to running the script, user must already know the threshold values to identify DAPI cells as well as FITC (H2AX) positive cells. When thresholding, the cells should be red and the background dark.
Window outputs are suppressed until the end of the script*/
//Updated September 29, 2017, J. Bagnall

inputFolder = getDirectory("Choose input folder");
var allImages;
allImages = getFileList(inputFolder);
numberOfImages = allImages.length;


if (getVersion>="1.40e")
        setOption("display labels", true);
setBatchMode(true);
 

//Get thresholds from user
Dialog.create("Choose Intensity Threshold Values");
Dialog.addNumber("Low DAPI threshold:", 491);
Dialog.addNumber("High DAPI threshold:", 4095);
Dialog.addNumber("Low FITC threshold:",385);
Dialog.addNumber("High FITC threshold:", 4095);
Dialog.show();
lowDAPIThreshold = Dialog.getNumber();
highDAPIThreshold = Dialog.getNumber();
lowFITCThreshold = Dialog.getNumber();
highFITCThreshold = Dialog.getNumber();

for (i=0; i<numberOfImages; i++){
	inputPath = inputFolder + allImages[i];
	open(inputPath);

	filename = File.name;
	print(filename);
	resultfilename = substring(filename, 0 , lastIndexOf(filename, ".")) + '_analyzed';	
	
	if(endsWith(filename, ".tif")){
		//Stack to images
		run("Stack to Images");
		//Image—001 is TxRed
		//Image—002 is DAPI
		//Image—003 is FITC

		FITC_name = getTitle();
		DAPI_name = substring(FITC_name, 0, lengthOf(FITC_name)-1)+”2”;

		selectWindow(DAPI_name);
		run("Duplicate...","title="+DAPI_name+"-1.tif");

		setAutoThreshold("Default dark");
		setThreshold(lowDAPIThreshold, highDAPIThreshold);

		run("Convert to Mask");
		run("Dilate");
		run("Watershed"); 	
		run("Set Measurements...", "area mean min shape integrated display redirect=" + DAPI_name + " decimal=3");
		run("Analyze Particles...", "size=0-Infinity circularity=0.00-1.00 show=Outlines display exclude clear summarize");
		selectWindow("Results");
		String.resetBuffer();
		labels = String.getResultsHeadings;
		File.append(labels, inputFolder+"/"+resultfilename+"DAPI.xls");
		String.copyResults();
		resultstring = String.paste;
		File.append(resultstring, inputFolder+"/"+resultfilename+"DAPI.xls");


		//Now do FITC
		selectWindow(FITC_name);
		run("Duplicate...","title="+FITC_name+"-1.tif");

		setAutoThreshold("Default dark");
		setThreshold(lowFITCThreshold, highFITCThreshold);

		run("Convert to Mask");
		run("Dilate");
		run("Watershed"); 	
		run("Set Measurements...", "area mean min shape integrated display redirect=" + FITC_name + " decimal=3");
		run("Analyze Particles...", "size=0-Infinity circularity=0.00-1.00 show=Outlines display exclude clear summarize");
		selectWindow("Results");
		String.resetBuffer();
		labels = String.getResultsHeadings;
		File.append(labels, inputFolder+"/"+resultfilename+"FITC.xls");
		String.copyResults();
		resultstring = String.paste;
		File.append(resultstring, inputFolder+"/"+resultfilename+"FITC.xls");
		String.resetBuffer();
	}
}

setBatchMode("exit & display");